= V5 MultiLine NoSorting TabWidth=30

H=";About this library"
The EAD Cookbook library is designed to allow for EAD markup and transformation according to the protocols of the EAD Cookbook.  It is intended for use with NoteTab Pro, ver. 4.85 or higher.  Not all functions will not work with NoteTab Light.   Customization will be necessary for it to work with NT Standard.  

In order for this Clip Library to work as intended, additional files need to be installed on your computer as discussed in the full documentation.

To learn more about clip libraries, consult the NoteTab help documentation.  This clip library may be modified to meet local needs.

Before attempting to use this Clipbook, read the instructions and installation requirements carefully.  Some variables need to be defined and default configuration settings should be set before using the Clipbook.

Chris Prom
University of Illinois Archives

15:37 10/11/01


H=";"


H=";Reference"
These clips are helpful for authoring EAD.  To view the EAD Cookbook and the Notetab Instructions, you need the Adobe Acrobat Reader, which is free from Adobe Software.

H="EAD Cookbook"
^!Shell c:\eadcb\readings\EADCookbook2002.pdf

H="Notetab Instructions"
^!Shell c:\eadcb\readings\EADCookbookForNotetab.pdf

H="Tag Library"
^!URL http://www.loc.gov/ead/tglib/

H="Application Guidelines"
^!URL http://lcweb.loc.gov/ead/ag/aghome.html

H="Language Codes"
^!URL http://lcweb.loc.gov/standards/iso639-2/langcodes.html


H=";"


H=";Files"
New EAD:  Opens template file and launches clips to begin a new EAD docuement.

Open Existing:  Lists all files in c:/eadcb/EADFiles and allows you to open one for editing.

Kill HTML Files:  Deletes (does not recycle) all HTML files stored in the c:/eadcb/EADFiles folder.

H="New EAD"
^!Set %PersonOrCorp%=^?[Personal Papers or Corporate Records?==_personal|corporate]
^!If ^%PersonOrCorp%=personal 1 else 2

:1
^!Open "c:\eadcb\templates\eadperson.tpl"
^!GOTO END
:2

^!Open "c:\eadcb\templates\eadcorporate.tpl"

:END

H="Open Existing EAD"
^!SetArray %Files%=^$GetFiles("c:\eadcb\EADFiles";*.xml;NAME)$
^!If ^%Files0%="" End1
^!Set %count%=1
^!Set %queryboxtext%="Open:==^%Files1%"
^!Goto 2

:1
^!If ^%count%>^%Files0% End2
^!Set %queryboxtext%="^%queryboxtext%|^%Files^%count%%"
:2
^!Inc %count%
^!GoTo 1

:End1
^!Prompt No files to open
^!goto exit
:End2

^!Set %FileToOpen%=^?{(H=^%count%)^%queryboxtext%}
^!Open ^%FileToOpen%

H="Kill HTML Files"
^!DeleteFile c:\eadcb\EADFiles\*.html
^!Prompt All HTML files from c:\eadcb\EADFiles have been deleted.

H="italics tags converter"
:start

^!Replace "<i>">>"<i>{title render=''italic''}" A
^!Replace "<i {.*}'>">>"<i>{title render=''italic''}" GRA
^!Replace "<i {.*}\n{.*}'>">>"<i>{title render=''italic''}" GRA
^!Replace "</i>">>"{/title}</i>" A
:END

H=";"


H=";XML"
These clips will validate and transform EAD files in the c:\eadcb\EADFiles folder.  They may also work on files in other directories, but this has not been fully tested.

Be very careful when editing these clips, since they are very dependent on directory structure and file naming conventions.

"Parse and Validate" launches Microsoft's command line XML validating parser: xmlint.  It is no longer available from the Microsoft site.  The file located in c:\eadcb\xmlint, with some limited documentation.  It generates a file (error.txt).  This file is automatically loaded into NoteTab after the program runs.  It will provide you with a line number and position where the error occured, or simply list the file name if everything is OK.  To go to the line number listed in the error file, FIRST MAKE SURE THE WORD WRAP FUNCTION IS TURNED OFF, then use CTRL+SHIFT+L.  In NoteTab Pro, there is a ine numbering feature available under the view menu. 

The clip "Make HTML" launches a DOS batch file (x.bat) located in c:/ead/batch, using some parameters to specify the file name and path of the source document and the sytlesheet.  These parameters are are passed by the clip.  The program XT invoked by the batch file was developed by James Clark: http://www.jclark.com/    XT is located in c:/ead/xt.  In order for it to work, you must have the Java Virtual Machine installed; see the Cookbook.  You are given the choice of five stylesheets for different display options.  If you wish to add other stylesheets, put them in the EAD/shared/styles directory and edit the clip (line 11) to give you an option to select them.  

"View in Browser" opens the HTML files you've just transformed using "Make HTML" in Windows' default browser.

"Move to Web Server" will move the files to your favorite web location on a server avaialable from your local workstation.  You must set the %Webfolder% variable to a local path for this to work correctly.  (If necessary, contact your sys admin to get the path to the webserver.)


H="Validate with NSGMLS"
^!CLOSE c:\ead\errors\errors.txt DISCARD
^!dos c:\eadcb\sp\bin\nsgmls.exe -s -fc:\eadcb\errors\errors.txt ^**
^!WAIT
^!open c:\eadcb\errors\errors.txt


H="MSValidator"
^!MoveCursor +1
^!InsertText ThIs Is A tEmPoRaRy PlAcEHoLdEr
^!Find "<eadi.*>{.*}</eadid>" WIRS
^!Set %eadidValue%=^$StrStripHTML("^$GetSelection$";FALSE)$
^!Set %extension%=^$GetExt(^**)$

^!Replace "ThIs Is A tEmPoRaRy PlAcEHoLdEr" >> "" SW

^!If ^%extension%=.xml 1
^!Prompt The current tabbed document is not an EAD file.  Please change the focus to an XML document.
^!Goto End

:1
^!CLOSE c:\eadcb\errors\error.txt DISCARD

^!Save AS c:\eadcb\EADFiles\^%eadidValue%.xml
^!set %xml%=^**
^!dos c:\eadcb\batch\xmlint.bat "^**"

^!WAIT
^!open ^%xml%
^!open c:\eadcb\errors\error.txt

:End

H="bigConversionTest"
:start
^!MoveCursor +1
^!Replace ^T>>"" SWA
^!Replace ^P>>"" SWA
^!Replace "''">>""" SWA
^!Replace "><">>">^P<" SWA
^!Replace " & ">>" &amp; " SWA
^!Replace "{title">>"<title" SWA
^!Replace "{/title}">>"</title>" SWA
^!Replace "italic"}">>"italic">" SWA
^!Replace "italic"}">>"italic">" SWA


^!MoveCursor +1
^!InsertText ThIs Is A tEmPoRaRy PlAcEHoLdEr
^!Find "<eadi.*>{.*}</eadid>" WIRS
^!Set %eadidValue%=^$StrStripHTML("^$GetSelection$";FALSE)$
^!Set %extension%=^$GetExt(^**)$

^!Save AS c:\eadcb\EADFiles\^%eadidValue%.xml
^!set %xml%=^**
^!open c:\eadcb\EADFiles\^%eadidValue%.xml

:End

H="big conversion"
:start
^!MoveCursor +1
^!Replace ^T>>"" SWA
^!Replace ^P>>"" SWA
^!Replace "''">>""" SWA
^!Replace "><">>">^P<" SWA
^!Replace " & ">>" &amp; " SWA
^!Replace "{title">>"<title" SWA
^!Replace "{/title}">>"</title>" SWA
^!Replace "italic"}">>"italic">" SWA
^!Replace "italic"}">>"italic">" SWA
:END

H="barCodes"
:start 
^!MoveCursor +1
^!Replace "^P">>" " SWA
^!Replace "<c0">>"~<c0" SWA
^!Replace "     ">>" " SWA
^!Replace "    ">>" " SWA
^!Replace "   ">>" " SWA
^!Replace "  ">>" " SWA
^!Replace "  ">>" " SWA
^!Replace " <c0">>"<c0" SWA
^!Replace "> <">>"><" SWA

^!Replace "~">>"^P~" SWA
^!WAIT
^!Replace "\n[^~]">>" \1" RSWA
^!WAIT
^!Replace "^P~">>"^P" SWA
^!WAIT
^!WAIT
^!WAIT
^!WAIT
^!WAIT
^!WAIT
^!WAIT
^!WAIT
^!WAIT
^!Replace "<container type="box">{.*}</container>">>"<container type="box">\t\1\t</container>" RSWA
^!Replace "</container>">>"^T</container>" SWA
^!Replace "^T^T</container>">>"^T</container>" SWA
^!Replace "</did>">>"\t\t\t\t\t\t\t</did>" RSWA

:END

H="175_thing"
:start

^!Replace "<tr> ^P      <td width="600" colspan="2"><a href="../facts.htm"><img src="../images/header.sm.gif" width="600" height="63" border="0"></a></td>^P    </tr>">>"" GA
^!Replace "jpg" width="{.*}" height="{.*}">">>"jpg" width="50%">" GRA
^!Replace "<tr>{.*}\n{.*}<td class="pages"{.*}\n{.*}\n{.*}\n{.*}\n{.*}\n{.*}\n{.*}</table>">>"</table>" GRA
:END

H="MARCXML_EXTRACTOR"
:start

^!Replace "<?xml version = "1.0" encoding="utf-8"?><collection xmlns="http://www.loc.gov/MARC21" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://www.loc.gov/MARC21 http://www.loc.gov/standards/marcxml/schema/MARC21.xsd" ><AdvInfo Date="07 SEP 2006" Time="16:43" Userid="MASTER" DatabaseCode="MAIN" LocationSrc="Database - Bibliographic" Contents="Bib and holdings - Level 5" SelectionCriteria="GL BS0906B"></AdvInfo><?xml version = "1.0" encoding="utf-8"?><collection xmlns="http://www.loc.gov/MARC21" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://www.loc.gov/MARC21 http://www.loc.gov/standards/marcxml/schema/MARC21.xsd" ><AdvInfo Date="07 SEP 2006" Time="16:43" Userid="MASTER" DatabaseCode="MAIN" LocationSrc="Database - Bibliographic" Contents="Bib and holdings - Level 5" SelectionCriteria="GL BS0906B"></AdvInfo><record  " >> "<?xml version = "1.0" encoding="utf-8"?><collection xmlns="http://www.loc.gov/MARC21" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://www.loc.gov/MARC21 http://www.loc.gov/standards/marcxml/schema/MARC21.xsd" ><AdvInfo Date="07 SEP 2006" Time="16:43" Userid="MASTER" DatabaseCode="MAIN" LocationSrc="Database - Bibliographic" Contents="Bib and holdings - Level 5" SelectionCriteria="GL BS0906B"></AdvInfo><?xml version = "1.0" encoding="utf-8"?><collection xmlns="http://www.loc.gov/MARC21" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://www.loc.gov/MARC21 http://www.loc.gov/standards/marcxml/schema/MARC21.xsd" ><AdvInfo Date="07 SEP 2006" Time="16:43" Userid="MASTER" DatabaseCode="MAIN" LocationSrc="Database - Bibliographic" Contents="Bib and holdings - Level 5" SelectionCriteria="GL BS0906B"></AdvInfo><?xml version = "1.0" encoding="utf-8"?><collection xmlns="http://www.loc.gov/MARC21" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://www.loc.gov/MARC21 http://www.loc.gov/standards/marcxml/schema/MARC21.xsd" ><AdvInfo Date="07 SEP 2006" Time="16:43" Userid="MASTER" DatabaseCode="MAIN" LocationSrc="Database - Bibliographic" Contents="Bib and holdings - Level 5" SelectionCriteria="GL BS0906B"></AdvInfo><record   " GA

^!Replace "</record></collection>" >> "</record></collection></collection>" GA


:END

H="Make HTML"
^!Save
^!Set %base%=^$GetPath(^**)$
^!Set %fileprefix%=^$GetName(^**)$
^!Set %extension%=^$GetExt(^**)$
^!If ^%extension%=.xml 1
^!Prompt The current tabbed document is not an EAD file.  Please change the focus to an XML document.
^!Goto End
:1
^!Set %xmlpath%=^**
^!Set %htmlpath%=^%base%^%fileprefix%.html
^!Set %stylesheet%=^?{(T=L,H=12)Choose a stylesheet:==saxon02t2002|saxon02a2002|saxon01a2002_test|saxon02rism2002|saxon02f2002|dsc15}
^!Set %xslpath%=c:\eadcb\shared\styles\^%stylesheet%.xsl

^!Set %Parser%=^?{Choose a Transfom Engine:==saxon|xt}

^!dos c:\eadcb\batch\^%Parser%.bat ^%xmlpath% ^%xslpath% 


H="View in Browser"
^!Set %extension%=^$GetExt(^**)$
^!If ^%extension%=.xml 0
^!Prompt The current tabbed document is not an EAD file.  Please change the focus to an XML document.
^!Goto End

:0
^!Set %base%=^$GetPath(^**)$
^!Set %fileprefix%=^$GetName(^**)$
^!Set %htmlpath%=^%base%^%fileprefix%f.html

^!If ^%stylesheet%=Illinois 1 ELSE 2

:1
^!Set %htmlpath%=^%base%^%fileprefix%f.html
^!Goto URL

:2
^!Set %htmlpath%=^%base%^%fileprefix%f.html

:URL
^!URL ^%htmlpath%

:End



H="Move to Web Server"
; This clip moves the xml and html files to the webserver you designate in the WebFolder variable
; Make HTML clip must be run first
; It can only be used if you have direct access to the webserver from your desktop.  If not, use FTP to transfer the files.

; Set this variable to the path to your webserver.  This can be a lettered drive or a share on a network.
^!Set %WebFolder%=//path/to/your/web/folder

^!Save
^!If ^%stylesheet%="" Error
^!Set %base%=^$GetPath(^**)$
^!Set %fileprefix%=^$GetName(^**)$
^!Set %htmlpath%=^%base%^%fileprefix%.html
^!If ^%stylesheet%="eadcbs3" 1
^!If ^%stylesheet%="UIDefault" 1
^!Set %htmlpath%=^%base%^%fileprefix%.html
^!Set %xmlpath%=^%base%^%fileprefix%.xml
^!Goto Move

:1
^!Find "<eadi.*>{.*}</eadid>" WIRS
^!Set %eadidValue%=^$StrStripHTML("^$GetSelection$";FALSE)$
^!Set %htmlpath%=^%base%^%eadidValue%*.html

:Move
^!CopyFile ^%htmlpath% ^%webfolder%
^!CopyFile ^%xmlpath% ^%webfolder%
^!Goto end

:Error
^!Prompt You must run Make HTML clip before moving files to the web server!

:end

H=";"


H=";METS Processing"


H="Validate METS Object"
^!CLOSE c:\eadcb\errors\metserror.txt DISCARD
^!set %xml%=^**
^!dos c:\jdk1.3.1_02\bin\java.exe sax.Counter -np -v -s ^** 2> C:\eadcb\errors\metserror.txt 
^!WAIT
^!open c:\eadcb\errors\metserror.txt

H=";"


H=";Top Level Metadata"
After creating a new document, work through these to add the metadata specified in each clip.

H="<bioghist>"
<bioghist altrender="biography" encodinganalog="545" id="a2">
<head>Biography of </head>
<p>^&</p>
</bioghist>

H="<chronlist>"

<chronlist>
<listhead>
<head01>Date</head01>
<head02>Event</head02>
</listhead>
^&
</chronlist>

H="<chronitem>"

<chronitem>
<date>^?[Date:]</date>
<event>^?[Event:]</event>
</chronitem>


H="<scopecontent>"
<scopecontent encodinganalog="520" id="a3">
<head>Scope and Contents</head>
<p>^&</p>
</scopecontent>

H="<organization>"
<organization encodinganalog="351$a" id="a4">
<head>Organization</head>
<p>^&</p>
</organization>


H="<relatedmaterial>"
<add>
<relatedmaterial encodinganalog="544 1" id="a6">
<head>Related Material</head>
<p>^&</p>
</relatedmaterial>
</add>



H="<arrangement>"
<arrangement encodinganalog="351$b" id="a5">
<head>Arrangement</head>
<p>^&</p>
</arrangement>

H="<otherfindaid>"
<add>
<otherfindaid encodinganalog="555" id="a8">
<head>Other Finding Aid</head>
<p>^&</p>
</otherfindaid>
</add>

H="<separated material>"
<add>
<separatedmaterial encodinganalog="544 0" id="a7">
<head>Separated Material</head>
<p>^&</p>
</separatedmaterial>
</add>


H="<index>"
<add>
<index id="a9">
<head>Index</head>
<p>^&</p>
</index>
</add>

H="<bibliography>"
<add>
<bibliography id="a10">
<head>Bibliography</head>
<p>^&</p>
</bibliography>
</add>

H="<odd>"
<odd encodinganalog="500" id="a11">
<head>Other Descriptive Data</head>
<p>^&</p>
</odd>


H=";"


H=";Controlled Access"
This section Contains controlled access clips for the top level of the finding aid.  Be sure to set the %source% variable.  

H="<controlaccess> template"
;this variable must be set to the source for your controlled access vocabulary--see the Cookbook instructions
^!Set %source%=local
^!Prompt Enter Controlled access terms for each heading you desire to use.  Headings may be left blank.  Additional terms can be added under each heading with the with the "Add term" clip.


^!Set %perso%=^?{Person:}; %corpora%=^?{Corporate Body:}; %fam%=^?{Family Name}; %geog%=^?{Geographic Location:}; %sub%=^?{General Subject:}; %gen%=^?{Genre:}; %occup%=^?{Occupation:}; %fun%=^?{Function:}; %titl%=^?{Title:}

<controlaccess id="a12">
<head>Index Terms</head>
<p>This record series is indexed under the following controlled access subject terms.
</p>
	
^!If "^%perso%"="" Corp
	<controlaccess>
		<head>Persons:</head>
		<persname encodinganalog="700" source="^%source%">^%perso%</persname>

	</controlaccess>

:Corp
^!If "^%corpora%"="" Fam
	
	<controlaccess>
		<head>Organizations:</head>
		<corpname encodinganalog="710" source="^%source%">^%corpora%</corpname>

	</controlaccess>

:Fam
^!If "^%fam%"="" Geo
	
	<controlaccess>
		<head>Family Names:</head>
		<famname encodinganalog="600" source="^%source%">^%fam%</famname>

	</controlaccess>

:Geo
^!If "^%geog%"="" Subject
	
	<controlaccess>
		<head>Places:</head>
		<geogname encodinganalog="651" source="^%source%">^%geog%</geogname>

	</controlaccess>

:Subject
^!If "^%sub%"="" Genre
	
	<controlaccess>
		<head>Subjects:</head>
		<subject encodinganalog="650" source="^%source%">^%sub%</subject>

	</controlaccess>

:Genre
^!If "^%gen%"="" Occup
	
	<controlaccess>
		<head>Document Types:</head>
		<genreform encodinganalog="655" source="^%source%">^%gen%</genreform>

	</controlaccess>

:Occup
^!If "^%occup%"="" Function
	
	<controlaccess>
		<head>Occupations:</head>
		<occupation encodinganalog="656" source="^%source%">^%occup%</occupation>
		
	</controlaccess>

:Function
^!If "^%fun%"="" Titl
	
	<controlaccess>
		<head>Functions:</head>
		<function encodinganalog="657" source="^%source%">^%fun%</function>

	</controlaccess>

:Titl
^!If "^%titl%"="" Finish
	
	<controlaccess>
		<head>Titles:</head>
		<title encodinganalog="630" source="^%source%">^%titl%</title>

	</controlaccess>
	
:Finish
</controlaccess>

H="Add term"
;this variable must be set to the source for your controlled access vocabulary--see the Cookbook instructions
^!Set %source%=local


^!Set %controlaccesstype%=^?[(T=L;H=9)Which controlled access tag do you wish to insert?==_<persname>|<corpname>|<famname>|<geogname>|<subject>|<genreform>|<occupation>|<function>|<title>]

^!If "^%controlaccesstype%"="<persname>" person
^!If "^%controlaccesstype%"="<corpname>" corp
^!If "^%controlaccesstype%"="<famname>" fam
^!If "^%controlaccesstype%"="<geogname>" geog
^!If "^%controlaccesstype%"="<subject>" subj
^!If "^%controlaccesstype%"="<genreform>" genre
^!If "^%controlaccesstype%"="<occupation>" occup

^!If "^%controlaccesstype%"="<function>" func
^!If "^%controlaccesstype%"="<title>" title

^!goto end


:person
<persname encodinganalog="700" source="^%source%">^&</persname>
^!goto end

:corp
<corpname encodinganalog="710" source="^%source%">^&</corpname>
^!goto end

:"fam
<famname encodinganalog="600" source="^%source%">^&</famname>
^!goto end

:geog
<geogname encodinganalog="651" source="^%source%">^&</geogname>
^!goto end

:subj
<subject encodinganalog="650" source="^%source%">^&</subject>
^!goto end

:genre
<genreform encodinganalog="655" source="^%source%">^&</genreform>
^!goto end

:occup
<occupation encodinganalog="656" source="^%source%">^&</occupation>
^!goto end

:func
<function encodinganalog="657" source="^%source%">^&</function>
^!goto end

:title
<title encodinganalog="630" source="^%source%">^&</title>
^!goto end


:end

H=";"


H=";Administrative Information"
These are for the admininfo section of the finding aid.  There is really not much more to say about them.  They are all optional and can be used in any order.

H="<accessrestrict>"
<admininfo>
<accessrestrict id="a14" encodinganalog="506">
<head>Restrictions on Access</head>
<p>^&</p>
</accessrestrict>
</admininfo>


H="<userestrcit>"
<admininfo>
<userestrict encodinganalog="540" id="a15">
<head>Restrictions on Use</head>
<p>^&</p>
</userestrict>
</admininfo>

H="<custodhist>"
<admininfo>
<custodhist encodinganalog="561" id="a16">
<head>Custodial History</head>
<p>^&</p>
</custodhist>
</admininfo>

H="<altformavail>"
<admininfo>
<altformavail id="a17" encodinganalog="530">
<head>Alternative Form Available</head>
<p>^&</p>
</altformavail>
</admininfo>


H="<prefercite>"
<admininfo>
<prefercite encodinganalog="510" id="a18">
<head>Preferred Citation</head>
<p>^&</p>
</prefercite>
</admininfo>

H="<acqinfo>"
<admininfo>
<acqinfo encodinganalog="541" id="a19">
<head>Acquisition Information</head>
<p>^&</p>
</acqinfo>
</admininfo>


H="<processinfo>"
<admininfo>
<processinfo encodinganalog="583" id="a20">
<head>Processing Information</head>
<p>^&</p>
</processinfo>
</admininfo>


H="<appraisal>"
<admininfo>
<appraisal encodinganalog="583" id="a21">
<head>Appraisal Information</head>
</appraisal>
<p>^&</p>
</admininfo>


H="<accruals>"
<admininfo>
<accruals encodinganalog="584" id="a22">
<head>Accruals</head>
<p>^&</p>
</accruals>
</admininfo>

H=";"


H=";<dsc>"
These clips insert the component levels with a <container type="box"> element.  Type=folder is not included, but you can edit to add if desired.  So that you don't have to enter the box number each time, there is a clip to set a box number variable--reset it when moving to a new box.

H="Open <dsc>"
<dsc type="combined" id="a23">
<head>Detailed Description/Box and Folder Listing</head>

^&
</dsc>


H="Set box number"
^!Set %boxnumdummy%=^?[Enter box number]


H="Set Folder Number"
^!Set %FolderNumber%=^?{Enter Folder Number:=^%FolderNumber%}
^!Inc %FolderNumber%

H="1. <c01 level='series'>"
<c01 level="series">
<did><unittitle>^?[Unittitle:],<unitdate>^?[Unitdate:]</unitdate></unittitle></did>

^&


</c01>


H="2. <c02>"
^!Set %boxnum%=^%boxnumdummy%

  <c02><did><container type="box">^%boxnum%</container>
  <unittitle>^?[Unittitle:],<unitdate>^?[Unitdate:]</unitdate></unittitle></did>
  </c02>
^&

H="3. <c03>"
^!Set %boxnum%=^%boxnumdummy%

    <c03><did><container type="box">^%boxnum%</container>
    <unittitle>^?[Unittitle:],<unitdate>^?[Unitdate:]</unitdate></unittitle></did>
    </c03>
^&

H="4. <c04>"
^!Set %boxnum%=^%boxnumdummy%

      <c04><did><container type="box">^%boxnum%</container>
      <unittitle>^?[Unittitle:],<unitdate>^?[Unitdate:]</unitdate></unittitle></did>
      </c04>
^&

H="5. <c05>"
^!Set %boxnum%=^%boxnumdummy%

        <c05><did><container type="box">^%boxnum%</container>
        <unittitle>^?[Unittitle:],<unitdate>^?[Unitdate:]</unitdate></unittitle></did>
        </c05>
^&

H="6. <c06>"
^!Set %boxnum%=^%boxnumdummy%

          <c06><did><container type="box">^%boxnum%</container>
          <unittitle>^?[Unittitle:],<unitdate>^?[Unitdate:]</unitdate></unittitle></did>
          </c06>
^&

H="Set <c01> ID attributes"
^!SetCursor 1:1
^!Set %ID%=1

:Loop
^!Find "<c01.*>" IRS
^!Set %Selection%=^$GetSelection$
^!If "^%Selection%"="" EXIT
^!Insert "<c01 level="series" id="series^%ID%">"
^!Inc %ID%
^!Goto Loop



H=";"


H=";Optional <dsc> elements"
These are optional elements which can be added to the component levels in the <dsc> according to the Cookbook encoding protocol.  <emph> and <title> are supported throughout the document.

H="<bioghist>"
<bioghist><p>^&</p></bioghist>

H="<accessrestrict>"
<admininfo><accessrestrict><p>^&</p></accessrestrict></admininfo>

H="<emph>"
<emph render="^?[Render:==bold|_italic|underline|sub|super|quoted|boldquoted|boldunderline|bolditalic|boldsmcaps|smcaps]">^&</emph>

H="<note>"
<note><p>^&</p></note>

H="<odd>"
<odd><p>^&</p></odd>

H="<scopecontent>"
<scopecontent><p>^&</p></scopecontent>

H="<title>"
<title render="^?[Render:==bold|_italic|underline|sub|super|quoted|boldquoted|boldunderline|bolditalic|boldsmcaps|smcaps]">^&</title>

H="<userestrict>"
<admininfo><userestrict><p>^&</p></userestrict></admininfo>

H=";"


H=";Lists"
List elements can be added anywhere in the dsc and at certain points in the top level of the fining aid.  See the Cookbook instructions for full details.

H="<list>"

<list><head>^?[Head:]</head>
<item>^&</item>

</list>

H="<item>"

<item>^?</item>


H=";"


H=";Tables"
These clips will insert a table template for a table of two to five columns with equal column widths as a percentage of the available browser space.  If you wish to edit column witdths, it is possible after the template has been generated.

H="Table Template"
^!Set %cols%=^?[How many columns?==2|_3|4|5]
^!If ^%cols%=2 ^!Set %width%=50
^!If ^%cols%=3 ^!Set %width%=33
^!If ^%cols%=4 ^!Set %width%=25
^!If ^%cols%=5 ^!Set %width%=20


<table colnum="^%cols%">

  <tgroup>  

^!If ^%cols%>=1 ^!InsertText "     <colspec colwidth="^%width%"/> ^p"
^!If ^%cols%>=2 ^!InsertText "     <colspec colwidth="^%width%"/> ^p"
^!If ^%cols%>=3 ^!InsertText "     <colspec colwidth="^%width%"/> ^p"
^!If ^%cols%>=4 ^!InsertText "     <colspec colwidth="^%width%"/> ^p"
^!If ^%cols%=5 ^!InsertText "     <colspec colwidth="^%width%"/> ^p"

  </tgroup>

  <thead>
    <row>

^!If ^%cols%>=1 ^!InsertText "      <entry>^?[Column 1 heading:]</entry> ^p"
^!If ^%cols%>=2 ^!InsertText "      <entry>^?[Column 2 heading:]</entry> ^p"
^!If ^%cols%>=3 ^!InsertText "      <entry>^?[Column 3 heading:]</entry> ^p"
^!If ^%cols%>=4 ^!InsertText "      <entry>^?[Column 4 heading:]</entry> ^p"
^!If ^%cols%=5 ^!InsertText "      <entry>^?[Column 5 heading:]</entry> ^p"

    </row>
  </thead>

  <tbody>


  </tbody>

</table>

H="add row of data"
  <row>

^!If ^%cols%=2 ^!Clip two    
^!If ^%cols%=3 ^!Clip three
^!If ^%cols%=4 ^!Clip four
^!If ^%cols%=5 ^!Clip five
^!Insert ^p

  </row>
^!Insert ^p

H="reset col num variable"
^!Set %cols%=^?[How many columns?==2|_3|4|5]

H=";"


H=";Cross Reference"
These clips will place a cross reference in a document.  <ref> is for an internal cross reference.  <archref> is for an external cross reference to another url.  It works like the <a> tag in html and is useful for references to related material or other webpages.  Please note however, that it is not supported in the eadcbs stylessheets, only the UIDefault.  Both tags are valid at most any point in a finding aid however.

H="<archref>"

<archref href="^?[URL:]">^&</archref>

H="<ref>"

<ref target="^?[ID of target element:]">^&</ref>

H=";"


H=";Comment"


H="Comment"
<!-- ^& -->

H=";"


H=";"


H="_two"
    <entry>^?[Head for Column 1:]</entry>
    <entry>^?[Head for Column 2:]</entry>

H="_three"
    <entry>^?[Head for Column 1:]</entry>
    <entry>^?[Head for Column 2:]</entry>
    <entry>^?[Head for Column 3:]</entry>

H="_four"
    <entry>^?[Head for Column 1:]</entry>
    <entry>^?[Head for Column 2:]</entry>    
    <entry>^?[Head for Column 3:]</entry>
    <entry>^?[Head for Column 4:]</entry>

H="_five"
    <entry>^?[Head for Column 1:]</entry>
    <entry>^?[Head for Column 2:]</entry>    
    <entry>^?[Head for Column 3:]</entry>
    <entry>^?[Head for Column 4:]</entry>
    <entry>^?[Head for Column 5:]</entry>